Andrew Top | 8414344 | 2018-07-12 10:44:23 -0700 | [diff] [blame] | 1 | ; |
| 2 | ; jfdctint.asm - accurate integer FDCT (SSE2) |
| 3 | ; |
| 4 | ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB |
Kaido Kert | 0e7d696 | 2021-08-06 13:16:46 -0700 | [diff] [blame] | 5 | ; Copyright (C) 2016, 2020, D. R. Commander. |
Andrew Top | 8414344 | 2018-07-12 10:44:23 -0700 | [diff] [blame] | 6 | ; |
| 7 | ; Based on the x86 SIMD extension for IJG JPEG library |
| 8 | ; Copyright (C) 1999-2006, MIYASAKA Masaru. |
| 9 | ; For conditions of distribution and use, see copyright notice in jsimdext.inc |
| 10 | ; |
| 11 | ; This file should be assembled with NASM (Netwide Assembler), |
| 12 | ; can *not* be assembled with Microsoft's MASM or any compatible |
| 13 | ; assembler (including Borland's Turbo Assembler). |
| 14 | ; NASM is available from http://nasm.sourceforge.net/ or |
| 15 | ; http://sourceforge.net/project/showfiles.php?group_id=6208 |
| 16 | ; |
Kaido Kert | 0e7d696 | 2021-08-06 13:16:46 -0700 | [diff] [blame] | 17 | ; This file contains a slower but more accurate integer implementation of the |
Andrew Top | 8414344 | 2018-07-12 10:44:23 -0700 | [diff] [blame] | 18 | ; forward DCT (Discrete Cosine Transform). The following code is based |
| 19 | ; directly on the IJG's original jfdctint.c; see the jfdctint.c for |
| 20 | ; more details. |
Andrew Top | 8414344 | 2018-07-12 10:44:23 -0700 | [diff] [blame] | 21 | |
| 22 | %include "jsimdext.inc" |
| 23 | %include "jdct.inc" |
| 24 | |
| 25 | ; -------------------------------------------------------------------------- |
| 26 | |
| 27 | %define CONST_BITS 13 |
| 28 | %define PASS1_BITS 2 |
| 29 | |
| 30 | %define DESCALE_P1 (CONST_BITS - PASS1_BITS) |
| 31 | %define DESCALE_P2 (CONST_BITS + PASS1_BITS) |
| 32 | |
| 33 | %if CONST_BITS == 13 |
| 34 | F_0_298 equ 2446 ; FIX(0.298631336) |
| 35 | F_0_390 equ 3196 ; FIX(0.390180644) |
| 36 | F_0_541 equ 4433 ; FIX(0.541196100) |
| 37 | F_0_765 equ 6270 ; FIX(0.765366865) |
| 38 | F_0_899 equ 7373 ; FIX(0.899976223) |
| 39 | F_1_175 equ 9633 ; FIX(1.175875602) |
| 40 | F_1_501 equ 12299 ; FIX(1.501321110) |
| 41 | F_1_847 equ 15137 ; FIX(1.847759065) |
| 42 | F_1_961 equ 16069 ; FIX(1.961570560) |
| 43 | F_2_053 equ 16819 ; FIX(2.053119869) |
| 44 | F_2_562 equ 20995 ; FIX(2.562915447) |
| 45 | F_3_072 equ 25172 ; FIX(3.072711026) |
| 46 | %else |
| 47 | ; NASM cannot do compile-time arithmetic on floating-point constants. |
| 48 | %define DESCALE(x, n) (((x) + (1 << ((n) - 1))) >> (n)) |
| 49 | F_0_298 equ DESCALE( 320652955, 30 - CONST_BITS) ; FIX(0.298631336) |
| 50 | F_0_390 equ DESCALE( 418953276, 30 - CONST_BITS) ; FIX(0.390180644) |
| 51 | F_0_541 equ DESCALE( 581104887, 30 - CONST_BITS) ; FIX(0.541196100) |
| 52 | F_0_765 equ DESCALE( 821806413, 30 - CONST_BITS) ; FIX(0.765366865) |
| 53 | F_0_899 equ DESCALE( 966342111, 30 - CONST_BITS) ; FIX(0.899976223) |
| 54 | F_1_175 equ DESCALE(1262586813, 30 - CONST_BITS) ; FIX(1.175875602) |
| 55 | F_1_501 equ DESCALE(1612031267, 30 - CONST_BITS) ; FIX(1.501321110) |
| 56 | F_1_847 equ DESCALE(1984016188, 30 - CONST_BITS) ; FIX(1.847759065) |
| 57 | F_1_961 equ DESCALE(2106220350, 30 - CONST_BITS) ; FIX(1.961570560) |
| 58 | F_2_053 equ DESCALE(2204520673, 30 - CONST_BITS) ; FIX(2.053119869) |
| 59 | F_2_562 equ DESCALE(2751909506, 30 - CONST_BITS) ; FIX(2.562915447) |
| 60 | F_3_072 equ DESCALE(3299298341, 30 - CONST_BITS) ; FIX(3.072711026) |
| 61 | %endif |
| 62 | |
| 63 | ; -------------------------------------------------------------------------- |
| 64 | SECTION SEG_CONST |
| 65 | |
| 66 | alignz 32 |
| 67 | GLOBAL_DATA(jconst_fdct_islow_sse2) |
| 68 | |
| 69 | EXTN(jconst_fdct_islow_sse2): |
| 70 | |
| 71 | PW_F130_F054 times 4 dw (F_0_541 + F_0_765), F_0_541 |
| 72 | PW_F054_MF130 times 4 dw F_0_541, (F_0_541 - F_1_847) |
| 73 | PW_MF078_F117 times 4 dw (F_1_175 - F_1_961), F_1_175 |
| 74 | PW_F117_F078 times 4 dw F_1_175, (F_1_175 - F_0_390) |
| 75 | PW_MF060_MF089 times 4 dw (F_0_298 - F_0_899), -F_0_899 |
| 76 | PW_MF089_F060 times 4 dw -F_0_899, (F_1_501 - F_0_899) |
| 77 | PW_MF050_MF256 times 4 dw (F_2_053 - F_2_562), -F_2_562 |
| 78 | PW_MF256_F050 times 4 dw -F_2_562, (F_3_072 - F_2_562) |
| 79 | PD_DESCALE_P1 times 4 dd 1 << (DESCALE_P1 - 1) |
| 80 | PD_DESCALE_P2 times 4 dd 1 << (DESCALE_P2 - 1) |
| 81 | PW_DESCALE_P2X times 8 dw 1 << (PASS1_BITS - 1) |
| 82 | |
| 83 | alignz 32 |
| 84 | |
| 85 | ; -------------------------------------------------------------------------- |
| 86 | SECTION SEG_TEXT |
| 87 | BITS 32 |
| 88 | ; |
| 89 | ; Perform the forward DCT on one block of samples. |
| 90 | ; |
| 91 | ; GLOBAL(void) |
| 92 | ; jsimd_fdct_islow_sse2(DCTELEM *data) |
| 93 | ; |
| 94 | |
| 95 | %define data(b) (b) + 8 ; DCTELEM *data |
| 96 | |
| 97 | %define original_ebp ebp + 0 |
| 98 | %define wk(i) ebp - (WK_NUM - (i)) * SIZEOF_XMMWORD |
| 99 | ; xmmword wk[WK_NUM] |
| 100 | %define WK_NUM 6 |
| 101 | |
| 102 | align 32 |
| 103 | GLOBAL_FUNCTION(jsimd_fdct_islow_sse2) |
| 104 | |
| 105 | EXTN(jsimd_fdct_islow_sse2): |
| 106 | push ebp |
| 107 | mov eax, esp ; eax = original ebp |
| 108 | sub esp, byte 4 |
| 109 | and esp, byte (-SIZEOF_XMMWORD) ; align to 128 bits |
| 110 | mov [esp], eax |
| 111 | mov ebp, esp ; ebp = aligned ebp |
| 112 | lea esp, [wk(0)] |
| 113 | pushpic ebx |
| 114 | ; push ecx ; unused |
| 115 | ; push edx ; need not be preserved |
| 116 | ; push esi ; unused |
| 117 | ; push edi ; unused |
| 118 | |
| 119 | get_GOT ebx ; get GOT address |
| 120 | |
| 121 | ; ---- Pass 1: process rows. |
| 122 | |
| 123 | mov edx, POINTER [data(eax)] ; (DCTELEM *) |
| 124 | |
| 125 | movdqa xmm0, XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_DCTELEM)] |
| 126 | movdqa xmm1, XMMWORD [XMMBLOCK(1,0,edx,SIZEOF_DCTELEM)] |
| 127 | movdqa xmm2, XMMWORD [XMMBLOCK(2,0,edx,SIZEOF_DCTELEM)] |
| 128 | movdqa xmm3, XMMWORD [XMMBLOCK(3,0,edx,SIZEOF_DCTELEM)] |
| 129 | |
| 130 | ; xmm0=(00 01 02 03 04 05 06 07), xmm2=(20 21 22 23 24 25 26 27) |
| 131 | ; xmm1=(10 11 12 13 14 15 16 17), xmm3=(30 31 32 33 34 35 36 37) |
| 132 | |
| 133 | movdqa xmm4, xmm0 ; transpose coefficients(phase 1) |
| 134 | punpcklwd xmm0, xmm1 ; xmm0=(00 10 01 11 02 12 03 13) |
| 135 | punpckhwd xmm4, xmm1 ; xmm4=(04 14 05 15 06 16 07 17) |
| 136 | movdqa xmm5, xmm2 ; transpose coefficients(phase 1) |
| 137 | punpcklwd xmm2, xmm3 ; xmm2=(20 30 21 31 22 32 23 33) |
| 138 | punpckhwd xmm5, xmm3 ; xmm5=(24 34 25 35 26 36 27 37) |
| 139 | |
| 140 | movdqa xmm6, XMMWORD [XMMBLOCK(4,0,edx,SIZEOF_DCTELEM)] |
| 141 | movdqa xmm7, XMMWORD [XMMBLOCK(5,0,edx,SIZEOF_DCTELEM)] |
| 142 | movdqa xmm1, XMMWORD [XMMBLOCK(6,0,edx,SIZEOF_DCTELEM)] |
| 143 | movdqa xmm3, XMMWORD [XMMBLOCK(7,0,edx,SIZEOF_DCTELEM)] |
| 144 | |
| 145 | ; xmm6=( 4 12 20 28 36 44 52 60), xmm1=( 6 14 22 30 38 46 54 62) |
| 146 | ; xmm7=( 5 13 21 29 37 45 53 61), xmm3=( 7 15 23 31 39 47 55 63) |
| 147 | |
| 148 | movdqa XMMWORD [wk(0)], xmm2 ; wk(0)=(20 30 21 31 22 32 23 33) |
| 149 | movdqa XMMWORD [wk(1)], xmm5 ; wk(1)=(24 34 25 35 26 36 27 37) |
| 150 | |
| 151 | movdqa xmm2, xmm6 ; transpose coefficients(phase 1) |
| 152 | punpcklwd xmm6, xmm7 ; xmm6=(40 50 41 51 42 52 43 53) |
| 153 | punpckhwd xmm2, xmm7 ; xmm2=(44 54 45 55 46 56 47 57) |
| 154 | movdqa xmm5, xmm1 ; transpose coefficients(phase 1) |
| 155 | punpcklwd xmm1, xmm3 ; xmm1=(60 70 61 71 62 72 63 73) |
| 156 | punpckhwd xmm5, xmm3 ; xmm5=(64 74 65 75 66 76 67 77) |
| 157 | |
| 158 | movdqa xmm7, xmm6 ; transpose coefficients(phase 2) |
| 159 | punpckldq xmm6, xmm1 ; xmm6=(40 50 60 70 41 51 61 71) |
| 160 | punpckhdq xmm7, xmm1 ; xmm7=(42 52 62 72 43 53 63 73) |
| 161 | movdqa xmm3, xmm2 ; transpose coefficients(phase 2) |
| 162 | punpckldq xmm2, xmm5 ; xmm2=(44 54 64 74 45 55 65 75) |
| 163 | punpckhdq xmm3, xmm5 ; xmm3=(46 56 66 76 47 57 67 77) |
| 164 | |
| 165 | movdqa xmm1, XMMWORD [wk(0)] ; xmm1=(20 30 21 31 22 32 23 33) |
| 166 | movdqa xmm5, XMMWORD [wk(1)] ; xmm5=(24 34 25 35 26 36 27 37) |
| 167 | movdqa XMMWORD [wk(2)], xmm7 ; wk(2)=(42 52 62 72 43 53 63 73) |
| 168 | movdqa XMMWORD [wk(3)], xmm2 ; wk(3)=(44 54 64 74 45 55 65 75) |
| 169 | |
| 170 | movdqa xmm7, xmm0 ; transpose coefficients(phase 2) |
| 171 | punpckldq xmm0, xmm1 ; xmm0=(00 10 20 30 01 11 21 31) |
| 172 | punpckhdq xmm7, xmm1 ; xmm7=(02 12 22 32 03 13 23 33) |
| 173 | movdqa xmm2, xmm4 ; transpose coefficients(phase 2) |
| 174 | punpckldq xmm4, xmm5 ; xmm4=(04 14 24 34 05 15 25 35) |
| 175 | punpckhdq xmm2, xmm5 ; xmm2=(06 16 26 36 07 17 27 37) |
| 176 | |
| 177 | movdqa xmm1, xmm0 ; transpose coefficients(phase 3) |
| 178 | punpcklqdq xmm0, xmm6 ; xmm0=(00 10 20 30 40 50 60 70)=data0 |
| 179 | punpckhqdq xmm1, xmm6 ; xmm1=(01 11 21 31 41 51 61 71)=data1 |
| 180 | movdqa xmm5, xmm2 ; transpose coefficients(phase 3) |
| 181 | punpcklqdq xmm2, xmm3 ; xmm2=(06 16 26 36 46 56 66 76)=data6 |
| 182 | punpckhqdq xmm5, xmm3 ; xmm5=(07 17 27 37 47 57 67 77)=data7 |
| 183 | |
| 184 | movdqa xmm6, xmm1 |
| 185 | movdqa xmm3, xmm0 |
| 186 | psubw xmm1, xmm2 ; xmm1=data1-data6=tmp6 |
| 187 | psubw xmm0, xmm5 ; xmm0=data0-data7=tmp7 |
| 188 | paddw xmm6, xmm2 ; xmm6=data1+data6=tmp1 |
| 189 | paddw xmm3, xmm5 ; xmm3=data0+data7=tmp0 |
| 190 | |
| 191 | movdqa xmm2, XMMWORD [wk(2)] ; xmm2=(42 52 62 72 43 53 63 73) |
| 192 | movdqa xmm5, XMMWORD [wk(3)] ; xmm5=(44 54 64 74 45 55 65 75) |
| 193 | movdqa XMMWORD [wk(0)], xmm1 ; wk(0)=tmp6 |
| 194 | movdqa XMMWORD [wk(1)], xmm0 ; wk(1)=tmp7 |
| 195 | |
| 196 | movdqa xmm1, xmm7 ; transpose coefficients(phase 3) |
| 197 | punpcklqdq xmm7, xmm2 ; xmm7=(02 12 22 32 42 52 62 72)=data2 |
| 198 | punpckhqdq xmm1, xmm2 ; xmm1=(03 13 23 33 43 53 63 73)=data3 |
| 199 | movdqa xmm0, xmm4 ; transpose coefficients(phase 3) |
| 200 | punpcklqdq xmm4, xmm5 ; xmm4=(04 14 24 34 44 54 64 74)=data4 |
| 201 | punpckhqdq xmm0, xmm5 ; xmm0=(05 15 25 35 45 55 65 75)=data5 |
| 202 | |
| 203 | movdqa xmm2, xmm1 |
| 204 | movdqa xmm5, xmm7 |
| 205 | paddw xmm1, xmm4 ; xmm1=data3+data4=tmp3 |
| 206 | paddw xmm7, xmm0 ; xmm7=data2+data5=tmp2 |
| 207 | psubw xmm2, xmm4 ; xmm2=data3-data4=tmp4 |
| 208 | psubw xmm5, xmm0 ; xmm5=data2-data5=tmp5 |
| 209 | |
| 210 | ; -- Even part |
| 211 | |
| 212 | movdqa xmm4, xmm3 |
| 213 | movdqa xmm0, xmm6 |
| 214 | paddw xmm3, xmm1 ; xmm3=tmp10 |
| 215 | paddw xmm6, xmm7 ; xmm6=tmp11 |
| 216 | psubw xmm4, xmm1 ; xmm4=tmp13 |
| 217 | psubw xmm0, xmm7 ; xmm0=tmp12 |
| 218 | |
| 219 | movdqa xmm1, xmm3 |
| 220 | paddw xmm3, xmm6 ; xmm3=tmp10+tmp11 |
| 221 | psubw xmm1, xmm6 ; xmm1=tmp10-tmp11 |
| 222 | |
| 223 | psllw xmm3, PASS1_BITS ; xmm3=data0 |
| 224 | psllw xmm1, PASS1_BITS ; xmm1=data4 |
| 225 | |
| 226 | movdqa XMMWORD [wk(2)], xmm3 ; wk(2)=data0 |
| 227 | movdqa XMMWORD [wk(3)], xmm1 ; wk(3)=data4 |
| 228 | |
| 229 | ; (Original) |
| 230 | ; z1 = (tmp12 + tmp13) * 0.541196100; |
| 231 | ; data2 = z1 + tmp13 * 0.765366865; |
| 232 | ; data6 = z1 + tmp12 * -1.847759065; |
| 233 | ; |
| 234 | ; (This implementation) |
| 235 | ; data2 = tmp13 * (0.541196100 + 0.765366865) + tmp12 * 0.541196100; |
| 236 | ; data6 = tmp13 * 0.541196100 + tmp12 * (0.541196100 - 1.847759065); |
| 237 | |
| 238 | movdqa xmm7, xmm4 ; xmm4=tmp13 |
| 239 | movdqa xmm6, xmm4 |
| 240 | punpcklwd xmm7, xmm0 ; xmm0=tmp12 |
| 241 | punpckhwd xmm6, xmm0 |
| 242 | movdqa xmm4, xmm7 |
| 243 | movdqa xmm0, xmm6 |
| 244 | pmaddwd xmm7, [GOTOFF(ebx,PW_F130_F054)] ; xmm7=data2L |
| 245 | pmaddwd xmm6, [GOTOFF(ebx,PW_F130_F054)] ; xmm6=data2H |
| 246 | pmaddwd xmm4, [GOTOFF(ebx,PW_F054_MF130)] ; xmm4=data6L |
| 247 | pmaddwd xmm0, [GOTOFF(ebx,PW_F054_MF130)] ; xmm0=data6H |
| 248 | |
| 249 | paddd xmm7, [GOTOFF(ebx,PD_DESCALE_P1)] |
| 250 | paddd xmm6, [GOTOFF(ebx,PD_DESCALE_P1)] |
| 251 | psrad xmm7, DESCALE_P1 |
| 252 | psrad xmm6, DESCALE_P1 |
| 253 | paddd xmm4, [GOTOFF(ebx,PD_DESCALE_P1)] |
| 254 | paddd xmm0, [GOTOFF(ebx,PD_DESCALE_P1)] |
| 255 | psrad xmm4, DESCALE_P1 |
| 256 | psrad xmm0, DESCALE_P1 |
| 257 | |
| 258 | packssdw xmm7, xmm6 ; xmm7=data2 |
| 259 | packssdw xmm4, xmm0 ; xmm4=data6 |
| 260 | |
| 261 | movdqa XMMWORD [wk(4)], xmm7 ; wk(4)=data2 |
| 262 | movdqa XMMWORD [wk(5)], xmm4 ; wk(5)=data6 |
| 263 | |
| 264 | ; -- Odd part |
| 265 | |
| 266 | movdqa xmm3, XMMWORD [wk(0)] ; xmm3=tmp6 |
| 267 | movdqa xmm1, XMMWORD [wk(1)] ; xmm1=tmp7 |
| 268 | |
| 269 | movdqa xmm6, xmm2 ; xmm2=tmp4 |
| 270 | movdqa xmm0, xmm5 ; xmm5=tmp5 |
| 271 | paddw xmm6, xmm3 ; xmm6=z3 |
| 272 | paddw xmm0, xmm1 ; xmm0=z4 |
| 273 | |
| 274 | ; (Original) |
| 275 | ; z5 = (z3 + z4) * 1.175875602; |
| 276 | ; z3 = z3 * -1.961570560; z4 = z4 * -0.390180644; |
| 277 | ; z3 += z5; z4 += z5; |
| 278 | ; |
| 279 | ; (This implementation) |
| 280 | ; z3 = z3 * (1.175875602 - 1.961570560) + z4 * 1.175875602; |
| 281 | ; z4 = z3 * 1.175875602 + z4 * (1.175875602 - 0.390180644); |
| 282 | |
| 283 | movdqa xmm7, xmm6 |
| 284 | movdqa xmm4, xmm6 |
| 285 | punpcklwd xmm7, xmm0 |
| 286 | punpckhwd xmm4, xmm0 |
| 287 | movdqa xmm6, xmm7 |
| 288 | movdqa xmm0, xmm4 |
| 289 | pmaddwd xmm7, [GOTOFF(ebx,PW_MF078_F117)] ; xmm7=z3L |
| 290 | pmaddwd xmm4, [GOTOFF(ebx,PW_MF078_F117)] ; xmm4=z3H |
| 291 | pmaddwd xmm6, [GOTOFF(ebx,PW_F117_F078)] ; xmm6=z4L |
| 292 | pmaddwd xmm0, [GOTOFF(ebx,PW_F117_F078)] ; xmm0=z4H |
| 293 | |
| 294 | movdqa XMMWORD [wk(0)], xmm7 ; wk(0)=z3L |
| 295 | movdqa XMMWORD [wk(1)], xmm4 ; wk(1)=z3H |
| 296 | |
| 297 | ; (Original) |
| 298 | ; z1 = tmp4 + tmp7; z2 = tmp5 + tmp6; |
| 299 | ; tmp4 = tmp4 * 0.298631336; tmp5 = tmp5 * 2.053119869; |
| 300 | ; tmp6 = tmp6 * 3.072711026; tmp7 = tmp7 * 1.501321110; |
| 301 | ; z1 = z1 * -0.899976223; z2 = z2 * -2.562915447; |
| 302 | ; data7 = tmp4 + z1 + z3; data5 = tmp5 + z2 + z4; |
| 303 | ; data3 = tmp6 + z2 + z3; data1 = tmp7 + z1 + z4; |
| 304 | ; |
| 305 | ; (This implementation) |
| 306 | ; tmp4 = tmp4 * (0.298631336 - 0.899976223) + tmp7 * -0.899976223; |
| 307 | ; tmp5 = tmp5 * (2.053119869 - 2.562915447) + tmp6 * -2.562915447; |
| 308 | ; tmp6 = tmp5 * -2.562915447 + tmp6 * (3.072711026 - 2.562915447); |
| 309 | ; tmp7 = tmp4 * -0.899976223 + tmp7 * (1.501321110 - 0.899976223); |
| 310 | ; data7 = tmp4 + z3; data5 = tmp5 + z4; |
| 311 | ; data3 = tmp6 + z3; data1 = tmp7 + z4; |
| 312 | |
| 313 | movdqa xmm7, xmm2 |
| 314 | movdqa xmm4, xmm2 |
| 315 | punpcklwd xmm7, xmm1 |
| 316 | punpckhwd xmm4, xmm1 |
| 317 | movdqa xmm2, xmm7 |
| 318 | movdqa xmm1, xmm4 |
| 319 | pmaddwd xmm7, [GOTOFF(ebx,PW_MF060_MF089)] ; xmm7=tmp4L |
| 320 | pmaddwd xmm4, [GOTOFF(ebx,PW_MF060_MF089)] ; xmm4=tmp4H |
| 321 | pmaddwd xmm2, [GOTOFF(ebx,PW_MF089_F060)] ; xmm2=tmp7L |
| 322 | pmaddwd xmm1, [GOTOFF(ebx,PW_MF089_F060)] ; xmm1=tmp7H |
| 323 | |
| 324 | paddd xmm7, XMMWORD [wk(0)] ; xmm7=data7L |
| 325 | paddd xmm4, XMMWORD [wk(1)] ; xmm4=data7H |
| 326 | paddd xmm2, xmm6 ; xmm2=data1L |
| 327 | paddd xmm1, xmm0 ; xmm1=data1H |
| 328 | |
| 329 | paddd xmm7, [GOTOFF(ebx,PD_DESCALE_P1)] |
| 330 | paddd xmm4, [GOTOFF(ebx,PD_DESCALE_P1)] |
| 331 | psrad xmm7, DESCALE_P1 |
| 332 | psrad xmm4, DESCALE_P1 |
| 333 | paddd xmm2, [GOTOFF(ebx,PD_DESCALE_P1)] |
| 334 | paddd xmm1, [GOTOFF(ebx,PD_DESCALE_P1)] |
| 335 | psrad xmm2, DESCALE_P1 |
| 336 | psrad xmm1, DESCALE_P1 |
| 337 | |
| 338 | packssdw xmm7, xmm4 ; xmm7=data7 |
| 339 | packssdw xmm2, xmm1 ; xmm2=data1 |
| 340 | |
| 341 | movdqa xmm4, xmm5 |
| 342 | movdqa xmm1, xmm5 |
| 343 | punpcklwd xmm4, xmm3 |
| 344 | punpckhwd xmm1, xmm3 |
| 345 | movdqa xmm5, xmm4 |
| 346 | movdqa xmm3, xmm1 |
| 347 | pmaddwd xmm4, [GOTOFF(ebx,PW_MF050_MF256)] ; xmm4=tmp5L |
| 348 | pmaddwd xmm1, [GOTOFF(ebx,PW_MF050_MF256)] ; xmm1=tmp5H |
| 349 | pmaddwd xmm5, [GOTOFF(ebx,PW_MF256_F050)] ; xmm5=tmp6L |
| 350 | pmaddwd xmm3, [GOTOFF(ebx,PW_MF256_F050)] ; xmm3=tmp6H |
| 351 | |
| 352 | paddd xmm4, xmm6 ; xmm4=data5L |
| 353 | paddd xmm1, xmm0 ; xmm1=data5H |
| 354 | paddd xmm5, XMMWORD [wk(0)] ; xmm5=data3L |
| 355 | paddd xmm3, XMMWORD [wk(1)] ; xmm3=data3H |
| 356 | |
| 357 | paddd xmm4, [GOTOFF(ebx,PD_DESCALE_P1)] |
| 358 | paddd xmm1, [GOTOFF(ebx,PD_DESCALE_P1)] |
| 359 | psrad xmm4, DESCALE_P1 |
| 360 | psrad xmm1, DESCALE_P1 |
| 361 | paddd xmm5, [GOTOFF(ebx,PD_DESCALE_P1)] |
| 362 | paddd xmm3, [GOTOFF(ebx,PD_DESCALE_P1)] |
| 363 | psrad xmm5, DESCALE_P1 |
| 364 | psrad xmm3, DESCALE_P1 |
| 365 | |
| 366 | packssdw xmm4, xmm1 ; xmm4=data5 |
| 367 | packssdw xmm5, xmm3 ; xmm5=data3 |
| 368 | |
| 369 | ; ---- Pass 2: process columns. |
| 370 | |
| 371 | ; mov edx, POINTER [data(eax)] ; (DCTELEM *) |
| 372 | |
| 373 | movdqa xmm6, XMMWORD [wk(2)] ; xmm6=col0 |
| 374 | movdqa xmm0, XMMWORD [wk(4)] ; xmm0=col2 |
| 375 | |
| 376 | ; xmm6=(00 10 20 30 40 50 60 70), xmm0=(02 12 22 32 42 52 62 72) |
| 377 | ; xmm2=(01 11 21 31 41 51 61 71), xmm5=(03 13 23 33 43 53 63 73) |
| 378 | |
| 379 | movdqa xmm1, xmm6 ; transpose coefficients(phase 1) |
| 380 | punpcklwd xmm6, xmm2 ; xmm6=(00 01 10 11 20 21 30 31) |
| 381 | punpckhwd xmm1, xmm2 ; xmm1=(40 41 50 51 60 61 70 71) |
| 382 | movdqa xmm3, xmm0 ; transpose coefficients(phase 1) |
| 383 | punpcklwd xmm0, xmm5 ; xmm0=(02 03 12 13 22 23 32 33) |
| 384 | punpckhwd xmm3, xmm5 ; xmm3=(42 43 52 53 62 63 72 73) |
| 385 | |
| 386 | movdqa xmm2, XMMWORD [wk(3)] ; xmm2=col4 |
| 387 | movdqa xmm5, XMMWORD [wk(5)] ; xmm5=col6 |
| 388 | |
| 389 | ; xmm2=(04 14 24 34 44 54 64 74), xmm5=(06 16 26 36 46 56 66 76) |
| 390 | ; xmm4=(05 15 25 35 45 55 65 75), xmm7=(07 17 27 37 47 57 67 77) |
| 391 | |
| 392 | movdqa XMMWORD [wk(0)], xmm0 ; wk(0)=(02 03 12 13 22 23 32 33) |
| 393 | movdqa XMMWORD [wk(1)], xmm3 ; wk(1)=(42 43 52 53 62 63 72 73) |
| 394 | |
| 395 | movdqa xmm0, xmm2 ; transpose coefficients(phase 1) |
| 396 | punpcklwd xmm2, xmm4 ; xmm2=(04 05 14 15 24 25 34 35) |
| 397 | punpckhwd xmm0, xmm4 ; xmm0=(44 45 54 55 64 65 74 75) |
| 398 | movdqa xmm3, xmm5 ; transpose coefficients(phase 1) |
| 399 | punpcklwd xmm5, xmm7 ; xmm5=(06 07 16 17 26 27 36 37) |
| 400 | punpckhwd xmm3, xmm7 ; xmm3=(46 47 56 57 66 67 76 77) |
| 401 | |
| 402 | movdqa xmm4, xmm2 ; transpose coefficients(phase 2) |
| 403 | punpckldq xmm2, xmm5 ; xmm2=(04 05 06 07 14 15 16 17) |
| 404 | punpckhdq xmm4, xmm5 ; xmm4=(24 25 26 27 34 35 36 37) |
| 405 | movdqa xmm7, xmm0 ; transpose coefficients(phase 2) |
| 406 | punpckldq xmm0, xmm3 ; xmm0=(44 45 46 47 54 55 56 57) |
| 407 | punpckhdq xmm7, xmm3 ; xmm7=(64 65 66 67 74 75 76 77) |
| 408 | |
| 409 | movdqa xmm5, XMMWORD [wk(0)] ; xmm5=(02 03 12 13 22 23 32 33) |
| 410 | movdqa xmm3, XMMWORD [wk(1)] ; xmm3=(42 43 52 53 62 63 72 73) |
| 411 | movdqa XMMWORD [wk(2)], xmm4 ; wk(2)=(24 25 26 27 34 35 36 37) |
| 412 | movdqa XMMWORD [wk(3)], xmm0 ; wk(3)=(44 45 46 47 54 55 56 57) |
| 413 | |
| 414 | movdqa xmm4, xmm6 ; transpose coefficients(phase 2) |
| 415 | punpckldq xmm6, xmm5 ; xmm6=(00 01 02 03 10 11 12 13) |
| 416 | punpckhdq xmm4, xmm5 ; xmm4=(20 21 22 23 30 31 32 33) |
| 417 | movdqa xmm0, xmm1 ; transpose coefficients(phase 2) |
| 418 | punpckldq xmm1, xmm3 ; xmm1=(40 41 42 43 50 51 52 53) |
| 419 | punpckhdq xmm0, xmm3 ; xmm0=(60 61 62 63 70 71 72 73) |
| 420 | |
| 421 | movdqa xmm5, xmm6 ; transpose coefficients(phase 3) |
| 422 | punpcklqdq xmm6, xmm2 ; xmm6=(00 01 02 03 04 05 06 07)=data0 |
| 423 | punpckhqdq xmm5, xmm2 ; xmm5=(10 11 12 13 14 15 16 17)=data1 |
| 424 | movdqa xmm3, xmm0 ; transpose coefficients(phase 3) |
| 425 | punpcklqdq xmm0, xmm7 ; xmm0=(60 61 62 63 64 65 66 67)=data6 |
| 426 | punpckhqdq xmm3, xmm7 ; xmm3=(70 71 72 73 74 75 76 77)=data7 |
| 427 | |
| 428 | movdqa xmm2, xmm5 |
| 429 | movdqa xmm7, xmm6 |
| 430 | psubw xmm5, xmm0 ; xmm5=data1-data6=tmp6 |
| 431 | psubw xmm6, xmm3 ; xmm6=data0-data7=tmp7 |
| 432 | paddw xmm2, xmm0 ; xmm2=data1+data6=tmp1 |
| 433 | paddw xmm7, xmm3 ; xmm7=data0+data7=tmp0 |
| 434 | |
| 435 | movdqa xmm0, XMMWORD [wk(2)] ; xmm0=(24 25 26 27 34 35 36 37) |
| 436 | movdqa xmm3, XMMWORD [wk(3)] ; xmm3=(44 45 46 47 54 55 56 57) |
| 437 | movdqa XMMWORD [wk(0)], xmm5 ; wk(0)=tmp6 |
| 438 | movdqa XMMWORD [wk(1)], xmm6 ; wk(1)=tmp7 |
| 439 | |
| 440 | movdqa xmm5, xmm4 ; transpose coefficients(phase 3) |
| 441 | punpcklqdq xmm4, xmm0 ; xmm4=(20 21 22 23 24 25 26 27)=data2 |
| 442 | punpckhqdq xmm5, xmm0 ; xmm5=(30 31 32 33 34 35 36 37)=data3 |
| 443 | movdqa xmm6, xmm1 ; transpose coefficients(phase 3) |
| 444 | punpcklqdq xmm1, xmm3 ; xmm1=(40 41 42 43 44 45 46 47)=data4 |
| 445 | punpckhqdq xmm6, xmm3 ; xmm6=(50 51 52 53 54 55 56 57)=data5 |
| 446 | |
| 447 | movdqa xmm0, xmm5 |
| 448 | movdqa xmm3, xmm4 |
| 449 | paddw xmm5, xmm1 ; xmm5=data3+data4=tmp3 |
| 450 | paddw xmm4, xmm6 ; xmm4=data2+data5=tmp2 |
| 451 | psubw xmm0, xmm1 ; xmm0=data3-data4=tmp4 |
| 452 | psubw xmm3, xmm6 ; xmm3=data2-data5=tmp5 |
| 453 | |
| 454 | ; -- Even part |
| 455 | |
| 456 | movdqa xmm1, xmm7 |
| 457 | movdqa xmm6, xmm2 |
| 458 | paddw xmm7, xmm5 ; xmm7=tmp10 |
| 459 | paddw xmm2, xmm4 ; xmm2=tmp11 |
| 460 | psubw xmm1, xmm5 ; xmm1=tmp13 |
| 461 | psubw xmm6, xmm4 ; xmm6=tmp12 |
| 462 | |
| 463 | movdqa xmm5, xmm7 |
| 464 | paddw xmm7, xmm2 ; xmm7=tmp10+tmp11 |
| 465 | psubw xmm5, xmm2 ; xmm5=tmp10-tmp11 |
| 466 | |
| 467 | paddw xmm7, [GOTOFF(ebx,PW_DESCALE_P2X)] |
| 468 | paddw xmm5, [GOTOFF(ebx,PW_DESCALE_P2X)] |
| 469 | psraw xmm7, PASS1_BITS ; xmm7=data0 |
| 470 | psraw xmm5, PASS1_BITS ; xmm5=data4 |
| 471 | |
| 472 | movdqa XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_DCTELEM)], xmm7 |
| 473 | movdqa XMMWORD [XMMBLOCK(4,0,edx,SIZEOF_DCTELEM)], xmm5 |
| 474 | |
| 475 | ; (Original) |
| 476 | ; z1 = (tmp12 + tmp13) * 0.541196100; |
| 477 | ; data2 = z1 + tmp13 * 0.765366865; |
| 478 | ; data6 = z1 + tmp12 * -1.847759065; |
| 479 | ; |
| 480 | ; (This implementation) |
| 481 | ; data2 = tmp13 * (0.541196100 + 0.765366865) + tmp12 * 0.541196100; |
| 482 | ; data6 = tmp13 * 0.541196100 + tmp12 * (0.541196100 - 1.847759065); |
| 483 | |
| 484 | movdqa xmm4, xmm1 ; xmm1=tmp13 |
| 485 | movdqa xmm2, xmm1 |
| 486 | punpcklwd xmm4, xmm6 ; xmm6=tmp12 |
| 487 | punpckhwd xmm2, xmm6 |
| 488 | movdqa xmm1, xmm4 |
| 489 | movdqa xmm6, xmm2 |
| 490 | pmaddwd xmm4, [GOTOFF(ebx,PW_F130_F054)] ; xmm4=data2L |
| 491 | pmaddwd xmm2, [GOTOFF(ebx,PW_F130_F054)] ; xmm2=data2H |
| 492 | pmaddwd xmm1, [GOTOFF(ebx,PW_F054_MF130)] ; xmm1=data6L |
| 493 | pmaddwd xmm6, [GOTOFF(ebx,PW_F054_MF130)] ; xmm6=data6H |
| 494 | |
| 495 | paddd xmm4, [GOTOFF(ebx,PD_DESCALE_P2)] |
| 496 | paddd xmm2, [GOTOFF(ebx,PD_DESCALE_P2)] |
| 497 | psrad xmm4, DESCALE_P2 |
| 498 | psrad xmm2, DESCALE_P2 |
| 499 | paddd xmm1, [GOTOFF(ebx,PD_DESCALE_P2)] |
| 500 | paddd xmm6, [GOTOFF(ebx,PD_DESCALE_P2)] |
| 501 | psrad xmm1, DESCALE_P2 |
| 502 | psrad xmm6, DESCALE_P2 |
| 503 | |
| 504 | packssdw xmm4, xmm2 ; xmm4=data2 |
| 505 | packssdw xmm1, xmm6 ; xmm1=data6 |
| 506 | |
| 507 | movdqa XMMWORD [XMMBLOCK(2,0,edx,SIZEOF_DCTELEM)], xmm4 |
| 508 | movdqa XMMWORD [XMMBLOCK(6,0,edx,SIZEOF_DCTELEM)], xmm1 |
| 509 | |
| 510 | ; -- Odd part |
| 511 | |
| 512 | movdqa xmm7, XMMWORD [wk(0)] ; xmm7=tmp6 |
| 513 | movdqa xmm5, XMMWORD [wk(1)] ; xmm5=tmp7 |
| 514 | |
| 515 | movdqa xmm2, xmm0 ; xmm0=tmp4 |
| 516 | movdqa xmm6, xmm3 ; xmm3=tmp5 |
| 517 | paddw xmm2, xmm7 ; xmm2=z3 |
| 518 | paddw xmm6, xmm5 ; xmm6=z4 |
| 519 | |
| 520 | ; (Original) |
| 521 | ; z5 = (z3 + z4) * 1.175875602; |
| 522 | ; z3 = z3 * -1.961570560; z4 = z4 * -0.390180644; |
| 523 | ; z3 += z5; z4 += z5; |
| 524 | ; |
| 525 | ; (This implementation) |
| 526 | ; z3 = z3 * (1.175875602 - 1.961570560) + z4 * 1.175875602; |
| 527 | ; z4 = z3 * 1.175875602 + z4 * (1.175875602 - 0.390180644); |
| 528 | |
| 529 | movdqa xmm4, xmm2 |
| 530 | movdqa xmm1, xmm2 |
| 531 | punpcklwd xmm4, xmm6 |
| 532 | punpckhwd xmm1, xmm6 |
| 533 | movdqa xmm2, xmm4 |
| 534 | movdqa xmm6, xmm1 |
| 535 | pmaddwd xmm4, [GOTOFF(ebx,PW_MF078_F117)] ; xmm4=z3L |
| 536 | pmaddwd xmm1, [GOTOFF(ebx,PW_MF078_F117)] ; xmm1=z3H |
| 537 | pmaddwd xmm2, [GOTOFF(ebx,PW_F117_F078)] ; xmm2=z4L |
| 538 | pmaddwd xmm6, [GOTOFF(ebx,PW_F117_F078)] ; xmm6=z4H |
| 539 | |
| 540 | movdqa XMMWORD [wk(0)], xmm4 ; wk(0)=z3L |
| 541 | movdqa XMMWORD [wk(1)], xmm1 ; wk(1)=z3H |
| 542 | |
| 543 | ; (Original) |
| 544 | ; z1 = tmp4 + tmp7; z2 = tmp5 + tmp6; |
| 545 | ; tmp4 = tmp4 * 0.298631336; tmp5 = tmp5 * 2.053119869; |
| 546 | ; tmp6 = tmp6 * 3.072711026; tmp7 = tmp7 * 1.501321110; |
| 547 | ; z1 = z1 * -0.899976223; z2 = z2 * -2.562915447; |
| 548 | ; data7 = tmp4 + z1 + z3; data5 = tmp5 + z2 + z4; |
| 549 | ; data3 = tmp6 + z2 + z3; data1 = tmp7 + z1 + z4; |
| 550 | ; |
| 551 | ; (This implementation) |
| 552 | ; tmp4 = tmp4 * (0.298631336 - 0.899976223) + tmp7 * -0.899976223; |
| 553 | ; tmp5 = tmp5 * (2.053119869 - 2.562915447) + tmp6 * -2.562915447; |
| 554 | ; tmp6 = tmp5 * -2.562915447 + tmp6 * (3.072711026 - 2.562915447); |
| 555 | ; tmp7 = tmp4 * -0.899976223 + tmp7 * (1.501321110 - 0.899976223); |
| 556 | ; data7 = tmp4 + z3; data5 = tmp5 + z4; |
| 557 | ; data3 = tmp6 + z3; data1 = tmp7 + z4; |
| 558 | |
| 559 | movdqa xmm4, xmm0 |
| 560 | movdqa xmm1, xmm0 |
| 561 | punpcklwd xmm4, xmm5 |
| 562 | punpckhwd xmm1, xmm5 |
| 563 | movdqa xmm0, xmm4 |
| 564 | movdqa xmm5, xmm1 |
| 565 | pmaddwd xmm4, [GOTOFF(ebx,PW_MF060_MF089)] ; xmm4=tmp4L |
| 566 | pmaddwd xmm1, [GOTOFF(ebx,PW_MF060_MF089)] ; xmm1=tmp4H |
| 567 | pmaddwd xmm0, [GOTOFF(ebx,PW_MF089_F060)] ; xmm0=tmp7L |
| 568 | pmaddwd xmm5, [GOTOFF(ebx,PW_MF089_F060)] ; xmm5=tmp7H |
| 569 | |
| 570 | paddd xmm4, XMMWORD [wk(0)] ; xmm4=data7L |
| 571 | paddd xmm1, XMMWORD [wk(1)] ; xmm1=data7H |
| 572 | paddd xmm0, xmm2 ; xmm0=data1L |
| 573 | paddd xmm5, xmm6 ; xmm5=data1H |
| 574 | |
| 575 | paddd xmm4, [GOTOFF(ebx,PD_DESCALE_P2)] |
| 576 | paddd xmm1, [GOTOFF(ebx,PD_DESCALE_P2)] |
| 577 | psrad xmm4, DESCALE_P2 |
| 578 | psrad xmm1, DESCALE_P2 |
| 579 | paddd xmm0, [GOTOFF(ebx,PD_DESCALE_P2)] |
| 580 | paddd xmm5, [GOTOFF(ebx,PD_DESCALE_P2)] |
| 581 | psrad xmm0, DESCALE_P2 |
| 582 | psrad xmm5, DESCALE_P2 |
| 583 | |
| 584 | packssdw xmm4, xmm1 ; xmm4=data7 |
| 585 | packssdw xmm0, xmm5 ; xmm0=data1 |
| 586 | |
| 587 | movdqa XMMWORD [XMMBLOCK(7,0,edx,SIZEOF_DCTELEM)], xmm4 |
| 588 | movdqa XMMWORD [XMMBLOCK(1,0,edx,SIZEOF_DCTELEM)], xmm0 |
| 589 | |
| 590 | movdqa xmm1, xmm3 |
| 591 | movdqa xmm5, xmm3 |
| 592 | punpcklwd xmm1, xmm7 |
| 593 | punpckhwd xmm5, xmm7 |
| 594 | movdqa xmm3, xmm1 |
| 595 | movdqa xmm7, xmm5 |
| 596 | pmaddwd xmm1, [GOTOFF(ebx,PW_MF050_MF256)] ; xmm1=tmp5L |
| 597 | pmaddwd xmm5, [GOTOFF(ebx,PW_MF050_MF256)] ; xmm5=tmp5H |
| 598 | pmaddwd xmm3, [GOTOFF(ebx,PW_MF256_F050)] ; xmm3=tmp6L |
| 599 | pmaddwd xmm7, [GOTOFF(ebx,PW_MF256_F050)] ; xmm7=tmp6H |
| 600 | |
| 601 | paddd xmm1, xmm2 ; xmm1=data5L |
| 602 | paddd xmm5, xmm6 ; xmm5=data5H |
| 603 | paddd xmm3, XMMWORD [wk(0)] ; xmm3=data3L |
| 604 | paddd xmm7, XMMWORD [wk(1)] ; xmm7=data3H |
| 605 | |
| 606 | paddd xmm1, [GOTOFF(ebx,PD_DESCALE_P2)] |
| 607 | paddd xmm5, [GOTOFF(ebx,PD_DESCALE_P2)] |
| 608 | psrad xmm1, DESCALE_P2 |
| 609 | psrad xmm5, DESCALE_P2 |
| 610 | paddd xmm3, [GOTOFF(ebx,PD_DESCALE_P2)] |
| 611 | paddd xmm7, [GOTOFF(ebx,PD_DESCALE_P2)] |
| 612 | psrad xmm3, DESCALE_P2 |
| 613 | psrad xmm7, DESCALE_P2 |
| 614 | |
| 615 | packssdw xmm1, xmm5 ; xmm1=data5 |
| 616 | packssdw xmm3, xmm7 ; xmm3=data3 |
| 617 | |
| 618 | movdqa XMMWORD [XMMBLOCK(5,0,edx,SIZEOF_DCTELEM)], xmm1 |
| 619 | movdqa XMMWORD [XMMBLOCK(3,0,edx,SIZEOF_DCTELEM)], xmm3 |
| 620 | |
| 621 | ; pop edi ; unused |
| 622 | ; pop esi ; unused |
| 623 | ; pop edx ; need not be preserved |
| 624 | ; pop ecx ; unused |
| 625 | poppic ebx |
| 626 | mov esp, ebp ; esp <- aligned ebp |
| 627 | pop esp ; esp <- original ebp |
| 628 | pop ebp |
| 629 | ret |
| 630 | |
| 631 | ; For some reason, the OS X linker does not honor the request to align the |
| 632 | ; segment unless we do this. |
| 633 | align 32 |